meson.build (941B)

      1 project('wig', 'c',
      2         meson_version: '>=1.8.0')
      3 
      4 # Fix math.h errors with glibc
      5 cc = meson.get_compiler('c')
      6 m_dep = cc.find_library('m', required : false)
      7 
      8 deps = [
      9   m_dep,
     10   dependency('wayland-client'),
     11   dependency('guile-3.0'),
     12   dependency('pixman-1'),
     13 ]
     14 
     15 # Set up wayland protocols
     16 wlr_protocols = dependency('wlr-protocols')
     17 wlr_protocols_data = wlr_protocols.get_variable('pkgdatadir')
     18 
     19 wl_mod = import('wayland')
     20 wayland_protocols = [
     21   wl_mod.scan_xml(wl_mod.find_protocol('xdg-shell')),
     22   wl_mod.scan_xml(join_paths(wlr_protocols_data, 'unstable/wlr-layer-shell-unstable-v1.xml'))
     23 ]
     24 
     25 # Set up devenv
     26 devenv = environment()
     27 devenv.append('GUILE_LOAD_PATH', join_paths(meson.current_source_dir(), 'scm'))
     28 meson.add_devenv(devenv)
     29 
     30 common_sources = files('src/surface.c', 'src/window.c')
     31 
     32 executable(
     33   'wig',
     34   wayland_protocols,
     35   common_sources + ['src/globals.c', 'src/main.c'],
     36   install : true,
     37   dependencies : deps
     38 )