meson.build (815B)

      1 project('scout', 'c')
      2 
      3 # Fix math.h errors with glibc
      4 cc = meson.get_compiler('c')
      5 m_dep = cc.find_library('m', required : false)
      6 
      7 deps = [
      8   dependency('glfw3'),
      9   dependency('gl'),
     10   dependency('epoxy'),
     11   dependency('inih'),
     12   m_dep
     13 ]
     14 
     15 common_sources = files(
     16   'src/util.c',
     17   'src/config.c'
     18 )
     19 
     20 scout_dir = join_paths(get_option('datadir'), 'scout')
     21 install_subdir('shaders', install_dir : scout_dir)
     22 
     23 absolute_shader_dir = join_paths(get_option('prefix'), scout_dir, 'shaders')
     24 
     25 # Make shaders available to devenv
     26 devenv = environment()
     27 devenv.set('SCOUT_SHADER_PATH', join_paths(meson.current_source_dir(), 'shaders'))
     28 meson.add_devenv(devenv)
     29 
     30 executable(
     31   'scout',
     32   common_sources + ['src/main.c'],
     33   install : true,
     34   dependencies : deps,
     35   c_args : ['-DSHADER_PATH="@0@"'.format(absolute_shader_dir)]
     36 )